//This is the ideal Fourier invariants.

ring rQ = 0, (q1,q2,q3,q4,q5), dp;
ideal Invariants = 
q3*q4-q2*q5,
q2*q4-q1*q5,
q2^2-q1*q3;

// This is the inverse of the Fourier transform.

matrix ptoq[5][5] =
1/16,3/8,1/16,1/4,1/4,
1/4,0,-1/4,1/2,-1/2,
3/8,-3/4,3/8,0,0,
1/4,0,-1/4,-1/2,1/2,
1/16,3/8,1/16,-1/4,-1/4;

// This is the ring of probability distributions. 

ring rP = 0,(p1,p2,p3,p4,p5),dp;

//This is the Fourier transform.

matrix qtop[5][5] =
1,1,1,1,1,
1,0,-1/3,0,1,
1,-1,1,-1,1,
1,1/2,0,-1/2,-1,
1,-1/2,0,1/2,-1;

ideal Fourier = qtop*transpose(maxideal(1));

// This is the list of polynomial invariants.

map F = rQ, Fourier;
ideal PInvariants =  F(Invariants); 

// This is the polynomial parametrization.

ring r = 0,(b0,b1,f0,f1),dp;

ideal P = 
b0^2*f0^5+b0^2*f1^5+2*b0*b1*f0^4*f1+2*b0*b1*f0*f1^4+b1^2*f0^5+b1^2*f1^5,
4*b0^2*f0^4*f1+4*b0^2*f0*f1^4+8*b0*b1*f0^3*f1^2+8*b0*b1*f0^2*f1^3+4*b1^2*f0^4*f1+4*b1^2*f0*f1^4,
6*b0^2*f0^3*f1^2+6*b0^2*f0^2*f1^3+12*b0*b1*f0^3*f1^2+12*b0*b1*f0^2*f1^3+6*b1^2*f0^3*f1^2+6*b1^2*f0^2*f1^3,
4*b0^2*f0^3*f1^2+4*b0^2*f0^2*f1^3+8*b0*b1*f0^4*f1+8*b0*b1*f0*f1^4+4*b1^2*f0^3*f1^2+4*b1^2*f0^2*f1^3,
b0^2*f0^4*f1+b0^2*f0*f1^4+2*b0*b1*f0^5+2*b0*b1*f1^5+b1^2*f0^4*f1+b1^2*f0*f1^4;

// This checks that the polynomial parametrization
// lies on the probability simplex.
// It requires suma.sing. Most likely, you should 
// change the directory where you saved this file. 

// If you do have this file, you should uncomment
// the following two lines.

// < "/home/lgp/singular/suma.sing";

// Suma(Substitute(0,P));

// This checks that the PInvariants vanish at
// the polynomial parametrization.

map Evaluate = rP, P;

// The following command takes a lot of space and time to
// finish for larger models.

// ideal Z = Evaluate(PInvariants);

setring rP;
ideal Z;
int i;
for (i=1; i<= size(PInvariants); i++)
{
  i;
  Z = PInvariants[i];
  setring r;
  Evaluate(Z);
  setring rP;
}