//This is the ideal Fourier invariants.

ring rQ = 0,(q1,q2,q3),dp;
 
ideal Invariants = 
q2^2-q1*q3;

// This is the inverse of the Fourier transform.

matrix ptoq[3][3] =
1/8,3/4,1/8,
1/2,0,-1/2,
3/8,-3/4,3/8;

// This is the ring of probability distributions. 

ring rP = 0,(p1,p2,p3),dp;

//This is the Fourier transform.

matrix qtop[3][3] =
1,1,1,
1,0,-1/3,
1,-1,1;


ideal Fourier = qtop*transpose(maxideal(1));

// This is the list of polynomial invariants.

map F = rQ, Fourier;
ideal PInvariants =  F(Invariants); 

// This is the polynomial parametrization.

ring r = 0,(d0,d1),dp;

ideal P = 
d0^4+d1^4,
4*d0^3*d1+4*d0*d1^3,
6*d0^2*d1^2;

// This checks that the polynomial parametrization
// lies on the probability simplex.
// It requires suma.sing. Most likely, you should 
// change the directory where you saved this file. 

// If you do have this file, you should uncomment
// the following two lines.

// < "/home/lgp/singular/suma.sing";

// Suma(Substitute(0,P));

// This checks that the PInvariants vanish at
// the polynomial parametrization.

map Evaluate = rP, P;

// The following command takes a lot of space and time to
// finish for larger models.

// ideal Z = Evaluate(PInvariants);

setring rP;
ideal Z;
int i;
for (i=1; i<= size(PInvariants); i++)
{
  i;
  Z = PInvariants[i];
  setring r;
  Evaluate(Z);
  setring rP;
}