//This is the ideal Fourier invariants.

ring rQ = 0,(q1,q2,q3,q4),dp; 

ideal Invariants = 
q3^2-q2*q4,
q2^2-q1*q4;

// This is the inverse of the Fourier transform.

matrix ptoq[5][4] =
1/64,9/32,3/8,21/64,
3/16,9/8,0,-21/16,
9/64,9/32,-9/8,45/64,
9/16,-9/8,0,9/16,
3/32,-9/16,3/4,-9/32;

// This is the ring of probability distributions. 

ring rP = 0,(p1,p2,p3,p4,p5),dp;

//This is the Fourier transform.

matrix qtop[4][5] =
1,1,1,1,1,
1,1/3,1/9,-1/9,-1/3,
1,0,-1/3,0,1/3,
1,-1/3,5/21,1/21,-1/7;


ideal Fourier = qtop*transpose(maxideal(1));

// This is the list of polynomial invariants.

map F = rQ, Fourier;
ideal PInvariants =  F(Invariants); 

// This is the polynomial parametrization.

ring r = 0,(d0,d1),dp;

ideal P = 
d0^4+3*d1^4,
12*d0^3*d1+12*d0*d1^3+24*d1^4,
18*d0^2*d1^2+18*d1^4,
36*d0^2*d1^2+72*d0*d1^3+36*d1^4,
24*d0*d1^3;

// This checks that the polynomial parametrization
// lies on the probability simplex.
// It requires suma.sing. Most likely, you should 
// change the directory where you saved this file. 

// If you do have this file, you should uncomment
// the following two lines.

// < "/home/lgp/singular/suma.sing";

// Suma(Substitute(1,P));

// This checks that the PInvariants vanish at
// the polynomial parametrization.

map Evaluate = rP, P;

// The following command takes a lot of space and time to
// finish for larger models.

// ideal Z = Evaluate(PInvariants);

setring rP;
ideal Z;
int i;
for (i=1; i<= size(PInvariants); i++)
{
  i;
  Z = PInvariants[i];
  setring r;
  Evaluate(Z);
  setring rP;
}