//This is the ideal Fourier invariants.

ring rQ = 0,(q1,q2,q3,q4,q5),dp;

ideal Invariants = 
q2*q3*q4-q1*q5^2;

// This is the inverse of the Fourier transform.

matrix ptoq[5][5] =
1/16,3/16,3/16,3/16,3/8,
3/16,9/16,-3/16,-3/16,-3/8,
3/16,-3/16,9/16,-3/16,-3/8,
3/16,-3/16,-3/16,9/16,-3/8,
3/8,-3/8,-3/8,-3/8,3/4;

// This is the ring of probability distributions. 

ring rP = 0,(p1,p2,p3,p4,p5),dp;

//This is the Fourier transform.

matrix qtop[5][5] =
1,1,1,1,1,
1,1,-1/3,-1/3,-1/3,
1,-1/3,1,-1/3,-1/3,
1,-1/3,-1/3,1,-1/3,
1,-1/3,-1/3,-1/3,1/3;


ideal Fourier = qtop*transpose(maxideal(1));

// This is the list of polynomial invariants.

map F = rQ, Fourier;
ideal PInvariants =  F(Invariants); 

// This is the polynomial parametrization.

ring r = 0,(c0,c1,c2,c3),dp;

ideal P = 
c0^3+c1^3+c2^3+c3^3,
3*c0^2*c1+3*c0*c1^2+3*c2^2*c3+3*c2*c3^2,
3*c0^2*c2+3*c0*c2^2+3*c1^2*c3+3*c1*c3^2,
3*c0^2*c3+3*c0*c3^2+3*c1^2*c2+3*c1*c2^2,
6*c0*c1*c2+6*c0*c1*c3+6*c0*c2*c3+6*c1*c2*c3;

// This checks that the polynomial parametrization
// lies on the probability simplex.
// It requires suma.sing. Most likely, you should 
// change the directory where you saved this file. 

// If you do have this file, you should uncomment
// the following two lines.

// < "/home/lgp/singular/suma.sing";

// Suma(Substitute(3,P));

// This checks that the PInvariants vanish at
// the polynomial parametrization.

map Evaluate = rP, P;

// The following command takes a lot of space and time to
// finish for larger models.

// ideal Z = Evaluate(PInvariants);

setring rP;
ideal Z;
int i;
for (i=1; i<= size(PInvariants); i++)
{
  i;
  Z = PInvariants[i];
  setring r;
  Evaluate(Z);
  setring rP;
}