//This is the ideal Fourier invariants.

ring rQ = 0,(q1,q2,q3,q4,q5,q6,q7,q8,q9,q10),dp;
 
ideal Invariants = 
q1*q6*q9-q2*q4*q10,
q3*q5*q9-q2*q7*q10,
q5*q6*q8-q4*q7*q10,
q2*q6*q8-q3*q4*q9,
q2*q5*q8-q1*q7*q9,
q3*q4*q5-q1*q6*q7,
q1*q3*q9^2-q2^2*q8*q10,
q1*q6^2*q8-q3*q4^2*q10,
q3*q5^2*q8-q1*q7^2*q10;

//This is the inverse of the Fourier transform.

matrix ptoq[10][10] = 
1/16,1/8,1/16,1/8,1/8,1/8,1/8,1/16,1/8,1/16,
1/8,0,-1/8,0,1/4,0,-1/4,-1/8,0,1/8,
1/16,-1/8,1/16,-1/8,1/8,-1/8,1/8,1/16,-1/8,1/16,
1/8,0,-1/8,1/4,0,-1/4,0,1/8,0,-1/8,
1/8,1/4,1/8,0,0,0,0,-1/8,-1/4,-1/8,
1/8,0,-1/8,-1/4,0,1/4,0,1/8,0,-1/8,
1/8,-1/4,1/8,0,0,0,0,-1/8,1/4,-1/8,
1/16,-1/8,1/16,1/8,-1/8,1/8,-1/8,1/16,-1/8,1/16,
1/8,0,-1/8,0,-1/4,0,1/4,-1/8,0,1/8,
1/16,1/8,1/16,-1/8,-1/8,-1/8,-1/8,1/16,1/8,1/16;

// This is the ring of probability distributions. 

ring rP = 0,(p1,p2,p3,p4,p5,p6,p7,p8,p9,p10),dp;

//This is the Fourier transform.

matrix qtop[10][10] =
1,1,1,1,1,1,1,1,1,1,
1,0,-1,0,1,0,-1,-1,0,1,
1,-1,1,-1,1,-1,1,1,-1,1,
1,0,-1,1,0,-1,0,1,0,-1,
1,1,1,0,0,0,0,-1,-1,-1,
1,0,-1,-1,0,1,0,1,0,-1,
1,-1,1,0,0,0,0,-1,1,-1,
1,-1,1,1,-1,1,-1,1,-1,1,
1,0,-1,0,-1,0,1,-1,0,1,
1,1,1,-1,-1,-1,-1,1,1,1;

ideal Fourier = qtop*transpose(maxideal(1));

// This is the list of polynomial invariants.

map F = rQ, Fourier;
ideal PInvariants =  F(Invariants); 

// This is the polynomial parametrization.

ring r = 0,(a0,a1,a2,b0,b1,b2,c0,c1,c2),dp;

ideal P = 
a0*b0*c0+2*a1*b1*c1+a2*b2*c2,
2*a0*b1*c1+2*a1*b0*c0+2*a1*b2*c2+2*a2*b1*c1,
a0*b2*c2+2*a1*b1*c1+a2*b0*c0,
2*a0*b0*c1+2*a1*b1*c0+2*a1*b1*c2+2*a2*b2*c1,
2*a0*b1*c0+2*a1*b0*c1+2*a1*b2*c1+2*a2*b1*c2,
2*a0*b2*c1+2*a1*b1*c0+2*a1*b1*c2+2*a2*b0*c1,
2*a0*b1*c2+2*a1*b0*c1+2*a1*b2*c1+2*a2*b1*c0,
a0*b0*c2+2*a1*b1*c1+a2*b2*c0,
2*a0*b1*c1+2*a1*b0*c2+2*a1*b2*c0+2*a2*b1*c1,
a0*b2*c0+2*a1*b1*c1+a2*b0*c2;

// This checks that the polynomial parametrization
// lies on the probability simplex. 
// It requires suma.sing. Most likely, you should 
// change the directory where you saved this file. 

// If you do have this file, you should uncomment
// the following two lines.

// < "/home/lgp/singular/suma.sing";

// Suma(Substitute(2,P));

// This checks that the PInvariants vanish at
// the polynomial parametrization.

map Evaluate = rP, P;

// The following command takes a lot of space and time to
// finish for larger models.

// ideal Z = Evaluate(PInvariants);

setring rP;
ideal Z;
int i;
for (i=1; i<= size(PInvariants); i++)
{
  i;
  Z = PInvariants[i];
  setring r;
  Evaluate(Z);
  setring rP;
}