restart;
with(LinearAlgebra):

# Define indeterminates

QParam := [q1,q2,q3,q4,q5]:
PParam := Matrix([[p1],[p2],[p3],[p4],[p5]]):

# Special Fourier parameterization and inverse

F := Matrix([[1,1,1,1,1],
[1,0,-1/3,0,1],
[1,-1,1,-1,1],
[1,1/2,0,-1/2,-1],
[1,-1/2,0,1/2,-1]]):

FI := Matrix([
[1/16,3/8,1/16,1/4,1/4],
[1/4,0,-1/4,1/2,-1/2],
[3/8,-3/4,3/8,0,0],
[1/4,0,-1/4,-1/2,1/2],
[1/16,3/8,1/16,-1/4,-1/4]
]):

# List of polynomial parametrizations

P0 := [
b0^2*f0^5+b0^2*f1^5+2*b0*b1*f0^4*f1+2*b0*b1*f0*f1^4+b1^2*f0^5+b1^2*f1^5,
4*b0^2*f0^4*f1+4*b0^2*f0*f1^4+8*b0*b1*f0^3*f1^2+8*b0*b1*f0^2*f1^3+4*b1^2*f0^4*f1+4*b1^2*f0*f1^4,
6*b0^2*f0^3*f1^2+6*b0^2*f0^2*f1^3+12*b0*b1*f0^3*f1^2+12*b0*b1*f0^2*f1^3+6*b1^2*f0^3*f1^2+6*b1^2*f0^2*f1^3,
4*b0^2*f0^3*f1^2+4*b0^2*f0^2*f1^3+8*b0*b1*f0^4*f1+8*b0*b1*f0*f1^4+4*b1^2*f0^3*f1^2+4*b1^2*f0^2*f1^3,
b0^2*f0^4*f1+b0^2*f0*f1^4+2*b0*b1*f0^5+2*b0*b1*f1^5+b1^2*f0^4*f1+b1^2*f0*f1^4]:

# Substitutions based on the model

P := P0:
P := subs(b0 = 1-b1, P):
P := subs(f0 = 1-f1, P):

# Check that the polynomial parametrization lies in the probability simplex

suma := 0:
for i from 1 to nops(P) do
suma := suma + P[i]:
od:
normal(expand(suma));

# Ideal of Invariants in Fourier coordinates

Invariants := Matrix([
q3*q4-q2*q5,
q2*q4-q1*q5,
q2^2-q1*q3
  ]):

# Ideal of Invariants in probability coordinates

Fourier := MatrixMatrixMultiply(F,PParam):

PInvariants := Invariants:
for i from 1 to nops(QParam) do
PInvariants := subs(QParam[i] = Fourier[i, 1], PInvariants):
od:

# Evaluation of Invariants at the polynomial/rational parametrization

num := op(PInvariants[1,1..-1])[1]:
for j from 1 to num do
coordpoly := PInvariants[1, j]:
for i from 1 to op(PParam[1..-1,1])[1] do
coordpoly := subs(PParam[i, 1] = P0[i], coordpoly):
od:
coordpoly :=expand(coordpoly):
lprint(j,coordpoly);
od: